Der Garten — 15 of 37

Carsten Kreysler

Release 10

Section - Tree-Garden

The tree-garden is a male room, south from the white door, in the outdoors. "[if unvisited]Endlich draußen an der frischen Luft. Ja, das tut gut! Um das Haus ist ein hübscher eingezäunter Garten, der durch Hecken in verschiedene Bereiche getrennt wird.[line break][end if][if the player is atop]Du sitzt auf dem Apfelbaum, siehst aber nichts außer dem Gras unter Dir durch die vielen Blätter hier oben.[otherwise]Du stehst in einem kleinen Teil des Gartens. Direkt neben Dir ragt ein Apfelbaum in die Höhe.[end if][paragraph break]Im Norden steht ein kleines, blaues Haus[if unvisited] bestehend aus einem Zimmer[end if]. [if vegetable-garden is unvisited and flower-garden is unvisited]Im Westen und im Nordwesten führen Pfade in weitere Bereiche des Gartens.[otherwise if vegetable-garden is unvisited]Im Nordwesten ist der Blumengarten und im Westen ein weiterer Gartenbereich.[otherwise if flower-garden is unvisited]Im Westen ist der Gemüsegarten und im Nordwesten ein weiterer Gartenbereich.[otherwise]Im Nordwesten ist der Blumengarten und im Westen der Gemüsegarten.[end if]".

The printed name of the tree-garden is "Baumgarten".

The apple-tree is a male scenery in the tree-garden. The printed name of the apple-tree is "Apfelbaum". Understand "baum" and "apfelbaum" and "stamm" as apple-tree. The description of it is "Ein kräftiger Apfelbaum[if the apple is atop], in dessen Baumkrone ein saftiger Apfel zwischen den dichten Blättern hängt[otherwise] - leider obstlos[end if]."

The treetop is a female part of the apple-tree. The printed name of the treetop is "Baumkrone". Understand "baumkrone" and "blatt [n]" and "blaetter [p]" and "ast [m]" and "aeste [p]" and "krone" as treetop. The description of treetop is "Dichte Äste und Blätter bilden die Baumkrone.[if the apple is atop and the old bucket is atop] Ein Apfel und ein Eimer hängen darin.[otherwise if the old bucket is atop] Ein Eimer hängt darin.[otherwise if the apple is atop] Ein Apfel hängt darin.[end if][if the bird is in the tree-garden] Ein Vogel sitzt ganz oben auf dem Baum.[end if]".

The apple is a male edible scenery in the tree-garden. The printed name of the apple is "Apfel". Understand "apfel" as apple. The description of the apple is "Ein kleiner rotbackiger Apfel.". The apple is atop.

The apple can be dirty. The apple is dirty.

A bucket is a kind of container.

A bucket can be empty. A bucket is usually empty.

The old bucket is a male scenery bucket. The printed name of the old bucket is "alt[^] Eimer". Understand "eimer" as old bucket. Understand "wasser" as old bucket while the old bucket is not empty. The description of it is "Ein alter verbeulter Eimer[if empty]. Zu Deiner Freude ist er ohne Löcher[otherwise] voller Wasser[end if].". The old bucket has carrying capacity 1.

Instead of inserting the apple into the old bucket:

if the old bucket is not empty:

if the apple is dirty:

say "Du wäschst den Apfel.";

now the apple is not dirty;

otherwise:

say "Hör auf den Apfel zu schrubben, da ist doch gar nichts dran.";

otherwise:

continue the action.

Instead of inserting the carrot into the old bucket:

if old bucket is not empty:

if the carrot is dirty:

say "Du wäschst etwas Erde von der Möhre.";

now the carrot is not dirty;

otherwise:

say "Noch sauberer wird die Möhre nicht.";

otherwise:

continue the action.

Instead of inserting something into the old bucket:

if old bucket is not empty:

say "Du hast keinen Grund [den Noun] abzuwaschen.";

rule fails;

otherwise:

continue the action.

After examining the treetop when the old bucket is off-stage:

say "Du siehst zwischen den Blättern einen Eimer an einem Ast baumeln. Wie der wohl da hingekommen ist?";

now the old bucket is in the tree-garden;

now the old bucket is atop.

Before climbing the apple-tree:

if the player is not atop:

now the player is atop;

if the apple-tree is not scored:

say "Du kletterst auf den Baum, was entgegen Deiner Erwartung sehr einfach geht - als wäre der Stamm nur dafür geschaffen.";

now the apple-tree is scored;

otherwise:

say "Du kletterst auf den Baum.";

if the old bucket is off-stage:

say "Hier oben zwischen den Blättern siehst Du einen Eimer an einem Ast baumeln.";

now the old bucket is in the tree-garden;

now the old bucket is atop;

otherwise:

say "Noch höher kannst Du nicht. Die Äste würden Dein Gewicht nicht tragen.";

stop the action.

Before entering the apple-tree:

try climbing the apple-tree;

stop the action.

Before going down when atop:

try getting off the apple-tree;

stop the action.

Before going up when the location is tree-garden:

try climbing the apple-tree;

stop the action.

Before getting off the apple-tree:

if the player is atop:

say "Du hüpfst geschmeidig vom Baum.";

now the player is not atop;

otherwise:

say "Du bist nicht auf dem Baum.";

stop the action.

Instead of exiting when the player is atop:

try silently getting off the apple-tree.

Before going or entering when the player is atop:

[say "(Du kletterst erst vom Baum.)[no line break]";]

try silently getting off the apple-tree.

Does the player mean climbing the apple-tree:

it is very likely.

Before taking the apple when the apple is atop:

if the player is atop:

now the apple is not a scenery;

now the apple is portable;

otherwise:

say "Du hüpfst ein wenig, aber Du kommst dennoch nicht an den Apfel heran.";

stop the action.

[oder so:

The apple is a male edible undescribed thing in the tree-garden.

oder

now the apple is not fixed in place.]

After taking the apple when the apple is atop:

now the apple is not atop;

say "Von hier oben kommst Du leicht an den Apfel. Er gehört Dir.".

Before taking the old bucket when the old bucket is atop:

if the player is atop:

now the old bucket is not a scenery;

now the old bucket is portable;

otherwise:

say "Der hängt einfach zu hoch. Da kommst Du von hier nicht heran.";

stop the action.

After taking the old bucket when the old bucket is atop:

now the old bucket is not atop;

say "Du musst Dich ordentlich strecken, um den Eimer zu erreichen, aber schließlich gelingt es Dir.".

Before taking something when the noun is not atop and the player is atop:

if the noun is faraway:

say "Auch von hier oben ist [der Noun] nicht für Dich erreichbar.";

otherwise:

say "Von hier oben gelangst Du nicht an [den Noun].";

stop the action.

Instead of attacking the treetop:

if the player is not atop:

say "Von hier unten kommst Du nicht an [den Noun].";

otherwise:

say "Du schüttelst an den Ästen[if the old bucket is atop], dadurch schaukelt der Eimer ein wenig hin und her[end if].".

Instead of attacking the apple-tree:

say "Du versuchst an dem Stamm zu schütteln, aber der ist einfach zu mächtig. Da bewegt sich gar nichts.".